Semnale cu modulatie de amplitudine

Universitatea Tehnica "Gh. Asachi", Iasi, Facultatea de Electronica si Telecomunicatii

Laboratorul de Semnale, Circuite si Sisteme

http://scs4.etc.tuiasi.ro

Breviar teo retic

Scopul lucrarii:

Familiarizarea cu formele de unda ale unui semnal cu modulatie in am plitudine. Calcularea si reprezentarea spectrului semnalului MA.

Rezumat teoretic:

Modulatia īn amplitudine a unui purtator armonic este procesul de transferare a caracteristicilor semnalului modulator asupra amplitudinii semnalului purtator. Din punct de vedere matematic, cea mai simpla modulatie īn amplitudine este modulatia de produs.

Presupunem semnalul modulator de forma sm(t) avand transformata Fourier Sm(omega) iar semnalul purtator sp(t) avand spectrul Sp(omega) . Semnalul MA este definit de relatia sMA(t) = sm(t)*sp(t) , adica produsul celor doua semnale. Vom nota cu SMA(omega) , spectrul semnalului MA.

Principial, realizarea semnalului sMA(t) consta īn utilizarea unui multiplicator ideal descris de pe intrarile caruia se aplica semnalul modulator si respectiv purtator:

[Maple OLE 2.0 Object]

Īn functie de domeniul de valori pentru care sunt construite, multiplicatoarele fizice sunt īn patru cadrane (ambele intrari pot avea orice polaritate), īn doua cadrane (numai una dintre intrari accepta semnale de orice polaritate) si īntr-un singur cadran (ambele intrari trebuie sa aiba o singura polaritate).

> restart:with(inttrans):assume(wm<wp):

> addtable(fourier,sm(t),Sm(omega),t,omega):

> addtable(fourier,sp(t),Sp(omega),t,omega):

> sMA:=(t)->k*sm(t)*sp(t):

> SMA:=(omega)->fourier(sMA(t),t,omega):

> sMA(t);

k*sm(t)*sp(t)

In acest caz, spectrul semnalului MA este de forma:

> SMA(omega);

1/2*k*int(Sm(_U1)*Sp(omega-_U1),_U1 = -infinity .. ...

In ce ce urmeaza, vom considera ca purtatoarea este semnal armonic:

> sp:=(t)->Ap*cos(wp*t);

sp := proc (t) options operator, arrow; Ap*cos(wp*t...

avand spectrul:

> SMA(omega);

k*Ap*(1/2*Sm(omega-wp)+1/2*Sm(omega+wp))

Mod de lucru

In afara de functiile incluse in libraria standard Maple, in aceasta lucrare vor fi utilizate cateva functii din libraria aditionala SCSlib.

Pentru calcularea transformatei Fourier a unor semnale:

Pentru trunchierea unor serii:

Pentru reprezentarea spectrelor unor semnale:

> restart:

> libname:="c:/Maple/SCSlib",libname:

> F:=FOURIER:

> assume(wm<wp):

> Sm:=(omega)->collect(F(sm(t),t,omega),m):

> Sp:=(omega)->F(sp(t),t,omega):

> sMA:=(t)->k*sm(t)*sp(t):

> SMA:=(omega)->collect(F(sMA(t),t,omega),m):

Exemple

Peste tot in cele ce urmeaza vom considera ca semnalul purtator este armonic:

> sp:=(t)->Ap*cos(wp*t);

sp := proc (t) options operator, arrow; Ap*cos(wp*t...

Semnal modulator armonic

Vom presupune in considratiile ce urmeaza ca semnalul modulator este armonic pe frecventa wm , avand si o componenta continua A0 :

> sm:=(t)->A0+Am*cos(wm*t+phi);

sm := proc (t) options operator, arrow; A0+Am*cos(w...

Raportul dintre amplitudinea componentei altenative si componenta continua ale semnalului modulator poarta numele de indice de modulatie in amplitudine si noteaza cu m . Putem scrie asadar ca:

> A0:=Am/m;

A0 := Am/m

Cu aceste notatii, semnalul modulator este:

> sm(t);

Am/m+Am*cos(wm*t+phi)

, iar spectrul sau este de forma:

> Sm(omega);

Am*Pi*(cos(phi)*Dirac(omega-wm)+cos(phi)*Dirac(omeg...

Semnalul MA este de forma:

> sMA(t);

k*(Am/m+Am*cos(wm*t+phi))*Ap*cos(wp*t)

, iar spectrul sau este de forma:

> SMA(omega);

1/2*k*Ap*Am*Pi*(cos(phi)*Dirac(omega-wp-wm)+cos(phi...
1/2*k*Ap*Am*Pi*(cos(phi)*Dirac(omega-wp-wm)+cos(phi...
1/2*k*Ap*Am*Pi*(cos(phi)*Dirac(omega-wp-wm)+cos(phi...

Figura Lissajoux care se obtine pe ecranul osciloscopului aplicand pe xOsc (CHANNEL1) semnalul modulator si yOsc (CHANNEL2) semnalul MA este de forma unei armonici incadrate de un trapez cu marimea bazei mici b si marimea bazei bazei mari B , date de relatiile:

> b:=2*Amin;B:=2*Amax;

b := 2*Amin

B := 2*Amax

unde Amin si Amax sunt valorile minima si maxima ale semnalului modulator date de relatiile:

> Amin:=A0-Am;Amax:=A0+Am;

Amin := Am/m-Am

Amax := Am/m+Am

Inlocuind in expresiile lui b si B , se obtine urmatoarea expresie pentru raportul b/B :

> simplify(b/B);

-(-1+m)/(1+m)

Vom particulariza in cele ce urmeaza amplitudinea si pulsatia semnalelor modulator si purtator si vom discuta influenta indicelui de modulatie asupra semnalului MA:

In functie de valoarea indicelui de modulatie exista mai multe situatii:

Cazul m<1 (submodulatie)

In acest caz componenta continua a semnalului modulator este mai mare decat componenta alternativa a semnalului ( Am < A0 ). Reprezentarile grafice s-au obtinut pentru m = 0.5 dar concluziile sunt valabile pentru orice valoare m < 1 :

> numvalues:={k=1,Ap=1,wp=10,Am=1,wm=1,phi=Pi/4,m=0.5}:

Forma de unda a semnalului MA este cuprinsa intre o anvelopa superioara data de sm(t) si o anvelopa inferioara data de -sm(t) .

> plot(eval([sm(t),-sm(t),sMA(t)],numvalues),t=-2*Pi..2*Pi,numpoints=400,color=[red,gray,black],linestyle=[1,1,1],labels=["t",""],title="Forme de unda pentru m<1: sm(t) (rosu),-sm(t) (gri), sMA(t) (negru)");

[Maple Plot]

Spectrele semnalului MA se obtine printr-o translare cu wp si -wp a spectrului semnalului modulator.

> PLOT3D(rpa(eval(SMA(omega),numvalues),omega,tipgrafic=D3,interval=-12..12,culoare=[0,0,0]),rpa(eval(Sm(omega),numvalues),omega,tipgrafic=D3,interval=-12..12,culoare=[1,0,0]),AXESSTYLE(NORMAL),AXESLABELS("omega","Re","Im"),TITLE("Spectre pentru m<1: Sm(omega) (rosu), SMA(omega) (negru)"));

[Maple Plot]

> plot(eval([[sm(t),sMA(t),t=-Pi..Pi],[sm(t),sm(t),t=-Pi..Pi],[sm(t),-sm(t),t=-Pi..Pi]],numvalues),numpoints=100,color=[black,red,gray],linestyle=[1,1,1],axes=box,title="Diagrama de modulatie pentru m<1");

[Maple Plot]

Cazul m=1 (modulatie 100%)

> numvalues:={k=1,Ap=1,wp=10,Am=1,wm=1,phi=Pi/4,m=1}:

In acest caz forma de unda si spectrul sunt ca in figura de mai jos pentru un defazaj intre semnale phi = Pi/4 .

> plot(eval([sm(t),-sm(t),sMA(t)],numvalues),t=-2*Pi..2*Pi,numpoints=400,color=[red,gray,black],linestyle=[1,1,1],labels=["t",""],title="Forme de unda pentru m=1: sm(t) (rosu),-sm(t) (gri), sMA(t) (negru)");

[Maple Plot]

Spectrele semnalului modulator si al semnalului MA sunt date in figura de mai jos:

> PLOT3D(rpa(eval(SMA(omega),numvalues),omega,tipgrafic=D3,interval=-12..12,culoare=[0,0,0]),rpa(eval(Sm(omega),numvalues),omega,tipgrafic=D3,interval=-12..12,culoare=[1,0,0]),AXESSTYLE(NORMAL),AXESLABELS("omega","Re","Im"),TITLE("Spectre pentru m=1: Sm(omega) (rosu), SMA(omega) (negru)"));

[Maple Plot]

> plot(eval([[sm(t),sMA(t),t=-Pi..Pi],[sm(t),sm(t),t=-Pi..Pi],[sm(t),-sm(t),t=-Pi..Pi]],numvalues),numpoints=100,color=[black,red,gray],linestyle=[1,1,1],axes=box,title="Diagrama de modulatie pentru m=1");

[Maple Plot]

Cazul m>1 (supramodulatie)

> numvalues:={k=1,Ap=1,wp=10,Am=1,wm=1,phi=Pi/4,m=2}:

In acest caz forma de unda si spectrul sunt ca in figura de mai jos pentru un defazaj intre semnale phi = Pi/4 .

> plot(eval([sm(t),-sm(t),sMA(t)],numvalues),t=-2*Pi..2*Pi,numpoints=400,color=[red,gray,black],linestyle=[1,1,1],labels=["t",""],title="Forme de unda pentru m>1: sm(t) (rosu),-sm(t) (gri), sMA(t) (negru)");

[Maple Plot]

Spectrele semnalului modulator si al semnalului MA sunt date in figura de mai jos:

> PLOT3D(rpa(eval(SMA(omega),numvalues),omega,tipgrafic=D3,interval=-12..12,culoare=[0,0,0]),rpa(eval(Sm(omega),numvalues),omega,tipgrafic=D3,interval=-12..12,culoare=[1,0,0]),AXESSTYLE(NORMAL),AXESLABELS("omega","Re","Im"),TITLE("Spectre pentru m>1: Sm(omega) (rosu), SMA(omega) (negru)"));

[Maple Plot]

> plot(eval([[sm(t),sMA(t),t=-Pi..Pi],[sm(t),sm(t),t=-Pi..Pi],[sm(t),-sm(t),t=-Pi..Pi]],numvalues),numpoints=100,color=[black,red,gray],linestyle=[1,1,1],axes=box,title="Diagrama de modulatie pentru m>1");

[Maple Plot]

Cazul IV. m = infinity (MAPS)

In acest caz componenta continua a semnalului este nula (m=infinity):

> numvalues:={k=1,Ap=1,wp=10,Am=1,wm=1,phi=Pi/4,m=infinity}:

In acest caz forma de unda a semnalului MA este ca in figura de mai jos:

> plot(eval([sm(t),-sm(t),sMA(t)],numvalues),t=-2*Pi..2*Pi,numpoints=400,color=[red,gray,black],linestyle=[1,1,1],labels=["t",""],title="Forme de unda pentru m=infinity: sm(t) (rosu),-sm(t) (gri), sMA(t) (negru)");

[Maple Plot]

Spectrele semnalului modulator si al semnalului MA sunt date in figura de mai jos:

> PLOT3D(rpa(eval(SMA(omega),numvalues),omega,tipgrafic=D3,interval=-12..12,culoare=[0,0,0]),rpa(eval(Sm(omega),numvalues),omega,tipgrafic=D3,interval=-12..12,culoare=[1,0,0]),AXESSTYLE(NORMAL),AXESLABELS("omega","Re","Im"),TITLE("Spectre pentru m=infinity: Sm(omega) (rosu), SMA(omega) (negru)"));

[Maple Plot]

Semnal modulator dreptunghiular

In acest semnalul modulator este de forma:

> sm:=(t)->Am*(Heaviside(t)-Heaviside(t-tau));

sm := proc (t) options operator, arrow; Am*(Heavisi...

Spectrul semnalului modulator este:

> Sm(omega):simplify(%);

-I*Am*(1-cos(tau*omega)+I*sin(tau*omega))/omega

Semnalul MA este de forma:

> sMA(t);

k*Am*(Heaviside(t)-Heaviside(t-tau))*Ap*cos(wp*t)

Spectrul semnalului MA este de forma:

> SMA(omega);

k*Am*Ap*(I*sin(tau*omega)*sin(wp*tau)*wp+I*cos(tau*...

Pentru obtinerea reprezentarilor grafice dam valori numerice constantelor care intervin in expresiile semnalelor:

> numvalues:={k=1,Ap=1,wp=10,Am=1,tau=2*Pi}:

> plot(eval([sm(t),-sm(t),sMA(t)],numvalues),t=-3*Pi..3*Pi,numpoints=100,color=[red,red,black],linestyle=[1,2,1],labels=["t","sMA(t)"],title="Forme de unda: modulatoare(rosu) si semnal MA(negru)");

[Maple Plot]

> PLOT3D(rpa(eval(SMA(omega),numvalues),omega,tipgrafic=D3,interval=-15..15,culoare=[0,0,0]),rpa(eval(Sm(omega),numvalues),omega,tipgrafic=D3,interval=-12..12,culoare=[1,0,0]),AXESSTYLE(NORMAL),AXESLABELS("omega","Re","Im"),TITLE("Spectre (m infinit): modulatoare(rosu) si semnalul MA(negru)"));

[Maple Plot]

Semnal modulator periodic dreptunghiular

In acest semnalul modulator este de forma:

> smg:=(t)->Am*(Heaviside(t)-Heaviside(t-tau));

smg := proc (t) options operator, arrow; Am*(Heavis...

> sm:=(t)->sum(smg(t-n*2*Pi/wm),`n`=-infinity..infinity);

sm := proc (t) options operator, arrow; sum(smg(t-2...

Spectrul semnalului modulator este:

> Sm(omega);

-Am*sum(I*Dirac(omega-n*wm)/n+-I*cos(tau*n*wm)*Dira...

Semnalul MA este in acest caz de forma:

> sMA(t);

k*sum(Am*(Heaviside(t-2*n*Pi/wm)-Heaviside(t-2*n*Pi...

Spectrul semnalului modulator este de forma:

> SMA(omega);

-k*Ap*Am*(1/2*sum(I*Dirac(omega-wp-n*wm)/n+-I*cos(t...
-k*Ap*Am*(1/2*sum(I*Dirac(omega-wp-n*wm)/n+-I*cos(t...

Pentru obtinerea reprezentarilor grafice dam valori constantelor care intervin in expresiile semanlelor:

> numvalues:={k=1,Ap=1,wp=10,Am=1,tau=Pi,wm=1}:

> plot(eval([eval(ts(sm(t),n=-5..5),numvalues),ts(-sm(t),n=-5..5),ts(sMA(t),n=-5..5)],numvalues), t=-5*Pi..5*Pi, numpoints=200, color=[red,red,black], linestyle=[1,2,1], labels=["t","sMA(t)"], title="Forme de unda: modulatoare(rosu) si semnal MA(negru)");

[Maple Plot]

Semnalul MA este de forma:

> PLOT3D(rpa(eval(ts(SMA(omega),n=-5..5),numvalues),omega,tipgrafic=D3,interval=-15..15,culoare=[0,0,0]),rpa(eval(ts(Sm(omega),n=-5..5),numvalues),omega,tipgrafic=D3,interval=-12..12,culoare=[1,0,0]),AXESSTYLE(NORMAL),AXESLABELS("omega","Re","Im"),TITLE("Spectre: modulatoare(rosu) si semnalul MA(negru)"));

[Maple Plot]

>

Probleme

Sa se reprezinte forma de unda a unui semnal MA cu purtatoare armonica si semnal modulator de tipul:

Sa se calculeze si sa se reprezinte grafic spectrul unui semnal MA cu purtatoare armonica si semnal modulator de tipul: